Azure Windows VM のイメージを取得しAzure Compute Gallery に格納する

# Microsoft.Compute/EncryptionAtHostを登録する
az feature register --namespace Microsoft.Compute --name EncryptionAtHost

# EncryptionAtHostの状態を確認する
# StateがRegisteredであること
az feature list -o table --query "[?contains(name, 'Microsoft.Compute/EncryptionAtHost')].{Name:name,State:properties.state}"

# リソースプロバイダーを登録する
az provider register --namespace Microsoft.Compute

.
├── main.bicep
└── parameters
    └── main.bicepparam

using '../main.bicep'

// リソースグループのパラメーター
param resourceGroupParam = {
  name: 'rg-vmimage'
}

// コンピューティングギャラリー、イメージ定義のパラメーター
param computeGalleryParam = {
  name: 'galvmimage'
  identifier: {
    offer: 'WindowsServer'
    publisher: 'MicrosoftWindowsServer'
    sku: '2025-datacenter-g2'
  }
  isAcceleratedNetworkSupported: true
  isHibernateSupported: true
  memory: {
    max: 16
    min: 4
  }
  imagename: 'az-winsrv-iis'
  osState: 'Generalized'
  osType: 'Windows'
  vCPUs: {
    max: 8
    min: 2
  }
}

// ネットワークセキュリティグループのパラメーター
param networkSecurityGroupParam = {
  name: 'nsg-vmimage'
  securityRules: [
    {
      name: 'AllowHTTPAccess'
      properties: {
        access: 'Allow'
        description: 'Test HTTP Access'
        destinationAddressPrefix: '*'
        destinationPortRange: '80'
        direction: 'Inbound'
        priority: 100
        protocol: '*'
        sourceAddressPrefix: '*'
        sourcePortRange: '*'
      }
    }
    {
      name: 'AllowRDPAccess'
      properties: {
        access: 'Allow'
        description: 'Test RDP Access'
        destinationAddressPrefix: '*'
        destinationPortRange: '3389'
        direction: 'Inbound'
        priority: 200
        protocol: '*'
        sourceAddressPrefix: '*'
        sourcePortRange: '*'
      }
    }
  ]
}

// 仮想ネットワークのパラメーター
param virtualNetworkParam = {
  name: 'vnet-vmimage'
  addressPrefixes: [
    '10.0.0.0/16'
  ]
  subnets: [
    {
      name: 'sub-vm'
      addressPrefix: '10.0.0.0/24'
    }
  ]
}

// 仮想マシンのパラメーター
param virtualMachineParam = {
  vmname: 'vm-vmimage'
  adminUser: 'azureuser'
  imageReference: {
    publisher: 'MicrosoftWindowsServer'
    offer: 'WindowsServer'
    sku: '2025-datacenter-azure-edition'
    version: 'latest'
  }
  nicConfigurations: [
    {
      nicname: 'nic-vmimage'
      ipConfigurations: [
        {
          name: 'ipconfig01'
          pipConfiguration: {
            pipname: 'pip-vmimage'
            skuName: 'Standard'
            publicIpNameSuffix: ''
            zones: []
          }
        }
      ]
      nicSuffix: ''
    }
  ]
  osDisk: {
    name: 'osdisk-vmimage'
    caching: 'ReadWrite'
    diskSizeGB: 128
    managedDisk: {
      storageAccountType: 'Standard_LRS'
    }
  }
  osType: 'Windows'
  vmSize: 'Standard_D2s_v3'
  zone: 0
}

param adminPassword = 'rQAZxs4w@Age'

targetScope = 'subscription'

@description('リソースグループのパラメーター')
param resourceGroupParam object

@description('コンピューティングギャラリー、イメージ定義のパラメーター')
param computeGalleryParam object

@description('ネットワークセキュリティグループのパラメーター')
param networkSecurityGroupParam object

@description('仮想ネットワークのパラメーター')
param virtualNetworkParam object

@description('仮想マシンのパラメーター')
param virtualMachineParam object

@secure()
@description('仮想マシンの管理者ユーザーパスワード')
param adminPassword string

// リソースグループの作成
module rg 'br/public:avm/res/resources/resource-group:0.4.0' = {
  scope: subscription()
  name: resourceGroupParam.name
  params: {
    name: resourceGroupParam.name
  }
}

// Azure コンピューティングギャラリー、イメージ定義の作成
module gallery 'br/public:avm/res/compute/gallery:0.8.1' = {
  scope: resourceGroup(resourceGroupParam.name)
  name: computeGalleryParam.name
  dependsOn: [
    rg
  ]
  params: {
    name: computeGalleryParam.name
    images: [
      {
        hyperVGeneration: 'V2'
        identifier: computeGalleryParam.identifier
        isAcceleratedNetworkSupported: computeGalleryParam.isAcceleratedNetworkSupported
        isHibernateSupported: computeGalleryParam.isHibernateSupported
        memory: computeGalleryParam.memory
        name: computeGalleryParam.imagename
        osState: computeGalleryParam.osState
        osType: computeGalleryParam.osType
        vCPUs: computeGalleryParam.vCPUs
      }
    ]
  }
}

// ネットワークセキュリティグループ(NSG)の作成
// IIS用のHTTPとSysprep用のRDPを開放する
module nsg 'br/public:avm/res/network/network-security-group:0.5.0' = {
  scope: resourceGroup(resourceGroupParam.name)
  name: networkSecurityGroupParam.name
  dependsOn: [
    rg
  ]
  params: {
    name: networkSecurityGroupParam.name
    securityRules: networkSecurityGroupParam.securityRules
  }
}

// 仮想ネットワーク、サブネットの作成
module vnet 'br/public:avm/res/network/virtual-network:0.5.2' = {
  scope: resourceGroup(resourceGroupParam.name)
  name: virtualNetworkParam.name
  dependsOn: [
    rg
  ]
  params: {
    name: virtualNetworkParam.name
    addressPrefixes: virtualNetworkParam.addressPrefixes
    subnets: [
      {
        name: virtualNetworkParam.subnets[0].name
        addressPrefix: virtualNetworkParam.subnets[0].addressPrefix
        networkSecurityGroupResourceId: nsg.outputs.resourceId
      }
    ]
  }
}

// イメージ作成用VMの作成
// VM作成時にNICも作成する
module vm 'br/public:avm/res/compute/virtual-machine:0.11.0' = {
  scope: resourceGroup(resourceGroupParam.name)
  name: virtualMachineParam.vmname
  dependsOn: [
    rg
  ]
  params: {
    name: virtualMachineParam.vmname
    adminUsername: virtualMachineParam.adminUser
    adminPassword: adminPassword
    extensionAadJoinConfig: {
      enabled: false
    }
    imageReference: virtualMachineParam.imageReference
    nicConfigurations: [
      {
        name: virtualMachineParam.nicConfigurations[0].nicname
        ipConfigurations: [
          {
            name: virtualMachineParam.nicConfigurations[0].ipConfigurations[0].name
            pipConfiguration: {
              name: virtualMachineParam.nicConfigurations[0].ipConfigurations[0].pipConfiguration.pipname
              publicIpNameSuffix: virtualMachineParam.nicConfigurations[0].ipConfigurations[0].pipConfiguration.publicIpNameSuffix
              zones: virtualMachineParam.nicConfigurations[0].ipConfigurations[0].pipConfiguration.zones
            } 
            subnetResourceId: vnet.outputs.subnetResourceIds[0]
          }
        ]
        nicSuffix: ''
      }
    ]
    osDisk: virtualMachineParam.osDisk
    osType: virtualMachineParam.osType
    vmSize: virtualMachineParam.vmSize
    zone: virtualMachineParam.zone
  }
}

# BicepテンプレートファイルでデプロイするAzureリソースを確認する
az deployment sub what-if -l japaneast -f main.bicep -p parameters/main.bicepparam

# Azureリソースをデプロイする
az deployment sub create -l japaneast -f main.bicep -p parameters/main.bicepparam

# IISをインストールする
az vm run-command invoke --command-id RunPowerShellScript --name vm-vmimage --resource-group rg-vmimage --scripts "Install-WindowsFeature -Name Web-Server"

REM Windows Serverを一般化する
cd C:\Windows\System32\Sysprep
sysprep /oobe /generalize /shutdown

# Azure VMの割り当てを解除する
az vm deallocate --resource-group rg-vmimage --name vm-vmimage

# Azure VMのステータスを確認する
# VM deallocated と表示されること
az vm get-instance-view --resource-group rg-vmimage --name vm-vmimage --query "instanceView.statuses[?starts_with(code, 'PowerState/')].displayStatus" --output tsv

# Azure VMのステータスを一般化する
az vm generalize --resource-group rg-vmimage --name vm-vmimage

# Azure VMから新しいイメージバージョンを作成する
az sig image-version create \
  --resource-group rg-vmimage \
  --gallery-name galvmimage \
  --gallery-image-definition az-winsrv-iis \
  --gallery-image-version 1.0.1 \
  --virtual-machine $(az vm show --resource-group rg-vmimage --name vm-vmimage --query "id" --output tsv)

# Compute GalleryのVMイメージからAzure VMを作成する
az vm create \
  --resource-group rg-vmimage \
  --name vm-fromgal \
  --image $(az sig image-version show --resource-group rg-vmimage --gallery-image-definition az-winsrv-iis --gallery-image-version 1.0.1 --gallery-name galvmimage --query "id" --output tsv) \
  --vnet-name vnet-vmimage \
  --subnet sub-vm \
  --admin-username azureuser \
  --admin-password rQAZxs4w@Age

# リソースをクリーンアップする
az group delete --resource-group rg-vmimage